      REAL FUNCTION SIGMA(E)
C     ELECTRON COLLISIONS WITH N2
C     ELASTIC SCATTERING
C     CROSS SECTION(CM^2)  :SIGMA
C     COLLISION ENERGY(KEV):E
C     T.Tabata, et al., At. Data Nucl. Data Tables.
      REAL A(12)
      DATA EMIN,EMAX,ETH /5.14E-5,5.22E+0,0.00E+0/
      DATA A /1.440E+4,1.284E+0,3.190E-5,-1.550E-1,9.000E-4,8.600E-1,
     >        9.140E+5,6.180E+0,2.437E-3,5.980E+0,2*0.0/
      DATA SIGMA0,ER /1.E-16,1.361E-2/
      SIGMA=0.0
      IF(E.LT.EMIN .OR. E.GT.EMAX) GO TO 9999
      E1=E-ETH
      SIGMA=F3(SIGMA0,ER,E1,A(1),A(2),A(3),A(4),A(5),A(6))
     >     +F2(SIGMA0,ER,E1,A(7),A(8),A(9),A(10))
 9999 RETURN
      END
C
      REAL FUNCTION F1(SIGMA0,ER,X,C1,C2)
        F1=SIGMA0*C1*(X/ER)**C2
      RETURN
      END
C
      REAL FUNCTION F2(SIGMA0,ER,X,C1,C2,C3,C4)
        F2=F1(SIGMA0,ER,X,C1,C2)
     >     /(1.+(X/C3)**(C2+C4))
      RETURN
      END
C
      REAL FUNCTION F3(SIGMA0,ER,X,C1,C2,C3,C4,C5,C6)
        F3=F1(SIGMA0,ER,X,C1,C2)
     >     /(1.+(X/C3)**(C2+C4)+(X/C5)**(C2+C6))
      RETURN
      END

