      REAL FUNCTION SIGMA(E)
C     ELECTRON COLLISIONS WITH N2
C     EMISSION FROM N(^2P -> ^2D^0) AT 149.3NM
C     CROSS SECTION(CM^2)  :SIGMA
C     COLLISION ENERGY(KEV):E
C     T.Tabata, et al., At. Data Nucl. Data Tables.
      REAL A(12)
      DATA EMIN,EMAX,ETH /2.05E-2,5.00E+0,2.04E-2/
      DATA A /5.290E-3,1.690E+0,4.600E-2,5.300E-2,5.400E-2,8.870E-1,
     >        3.910E-3,2.410E-1,1.281E-2,8.300E+0,2*0.0/
      DATA SIGMA0,ER /1.E-16,1.361E-2/
      SIGMA=0.0
      IF(E.LT.EMIN .OR. E.GT.EMAX) GO TO 9999
      E1=E-ETH
      SIGMA=F3(SIGMA0,ER,E1,A(1),A(2),A(3),A(4),A(5),A(6))
     >     +F2(SIGMA0,ER,E1,A(7),A(8),A(9),A(10))
 9999 RETURN
      END
C
      REAL FUNCTION F1(SIGMA0,ER,X,C1,C2)
        F1=SIGMA0*C1*(X/ER)**C2
      RETURN
      END
C
      REAL FUNCTION F2(SIGMA0,ER,X,C1,C2,C3,C4)
        F2=F1(SIGMA0,ER,X,C1,C2)
     >     /(1.+(X/C3)**(C2+C4))
      RETURN
      END
C
      REAL FUNCTION F3(SIGMA0,ER,X,C1,C2,C3,C4,C5,C6)
        F3=F1(SIGMA0,ER,X,C1,C2)
     >     /(1.+(X/C3)**(C2+C4)+(X/C5)**(C2+C6))
      RETURN
      END

